Rotate image by any angle vb.net

Public Class Form1

    Dim wiggle As Bitmap
    Dim tim As Timer

    Sub MoveWiggle(sender As Object, e As EventArgs)
        Static rot As Integer = 0
        Panel1.Refresh()

        Using g = Panel1.CreateGraphics()
            Using fnt As New Font("Consolas", 12), brsh As New SolidBrush(Color.Red)
                ' the text will not be rotated or translated
                g.DrawString($"{rot}°", fnt, brsh, New Point(10, 10))
            End Using
            ' the image will be rotated and translated
            g.TranslateTransform(100, 100)
            g.RotateTransform(CSng(rot))
            g.DrawImage(wiggle, -80, 0)
        End Using

        rot = (rot + 10) Mod 360

    End Sub

    Private Sub bnPause_Click(sender As Object, e As EventArgs) Handles bnPause.Click
        Static isPaused As Boolean = False
        If isPaused Then
            tim.Start()
            bnPause.Text = "Pause"
        Else
            tim.Stop()
            bnPause.Text = "Start"
        End If

        isPaused = Not isPaused

    End Sub

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        wiggle = New Bitmap("C:\temp\path3494.png")
        wiggle.SetResolution(96, 96) ' my image had a strange resolution
        tim = New Timer With {.Interval = 50}
        AddHandler tim.Tick, AddressOf MoveWiggle
        tim.Start()

    End Sub

    Private Sub Form1_Closing(sender As Object, e As EventArgs) Handles MyBase.Closing
        RemoveHandler tim.Tick, AddressOf MoveWiggle
        tim.Dispose()
        wiggle.Dispose()

    End Sub

End Class

Source: stackoverflow.com

Similar codes

0 vote335 views1 answer
VBA Sort RossetaCode
VBA
0 vote331 views1 answer
Vba check if class implements interface
VBA
0 vote331 views1 answer
Excel vba move down to next visible cell
VBA
0 vote360 views1 answer
Como ler subitem de um array em json usando vbnet
VBA
0 vote319 views1 answer
Vbscript abs
VBA
0 vote324 views1 answer
Telephon call in vba
VBA
2 votes315 views1 answer
Vba array contains
VBA
0 vote307 views1 answer
Excel vba hide columns
VBA
1 vote338 views2 answers
Vba function return array
VBA
0 vote334 views1 answer
Excel vba textbox forecolor disabled
VBA